Qt配置文件.pro语法总结

0.模板

QT       += core gui

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

TARGET      = FFmpegDemo
TEMPLATE    = app
MOC_DIR     = temp/moc
RCC_DIR     = temp/rcc
UI_DIR      = temp/ui
OBJECTS_DIR = temp/obj
DESTDIR     = $$PWD/../bin


DEFINES     += QT_DEPRECATED_WARNINGS
SOURCES     += main.cpp mainwindow.cpp
HEADERS     += mainwindow.h
FORMS       += mainwindow.ui
CONFIG      += warn_off c++11


INCLUDEPATH += $$PWD/ffmpeg
include ($$PWD/ffmpeg/ffmpeg.pri)

1. 注释

从“#”开始，到这一行结束。

# 这是注释

2. 模板变量

模板变量告诉qmake为这个应用程序生成哪种makefile。下面是可供使用的选择：

TEMPLATE = app

app -建立一个应用程序的makefile。这是默认值，所以如果模板没有被指定，这个将被使用。

lib - 建立一个库的makefile。

vcapp - 建立一个应用程序的VisualStudio项目文件。

vclib - 建立一个库的VisualStudio项目文件。

subdirs -这是一个特殊的模板，它可以创建一个能够进入特定目录并且为一个项目文件生成makefile并且为它调用make的makefile。

3. 基础文件设置

CODECFORSRC = GBK                #指定源文件编码方式

HEADERS += include/painter.h　　 #工程中包含的头文件

FORMS += forms/painter.ui　　    #工程中包含的.ui设计文件

SOURCES += sources/main.cpp sources/painter.cpp     #工程中包含的源文件

RESOURCES += qrc/painter.qrc     #工程中包含的资源文件

LIBS += -L folderPath　　        #引入的lib文件的路径  -L：引入路径

Release:LIBS += -L folderPath　　# release 版引入的lib文件路径

Debug:LIBS += -L folderPath 　　 # Debug 版引入的lib 文件路径

DEFINES += XX_XX_XXX  　　       #定义编译选项，在.h文件中就可以使用 ：#ifdefine xx_xx_xxx

RC_FILE = xxx.icns　　           #程序图标

4. 指定生成的应用程序名

TARGET = demo

5. 配置信息

CONFIG用来告诉qmake关于应用程序的配置信息。

例如

CONFIG+= qt warn_on release c++11

在这里使用“+=”，是因为我们添加我们的配置选项到任何一个已经存在中。这样做比使用“=”那样替换已经指定的所有选项是更安全的。

qt -告诉qmake这个应用程序是使用Qt来连编的。这也就是说qmake在连接和为编译添加所需的包含路径的时候会考虑到Qt库的。所有的Qt库都需要在CONFIG中添加之后才能使用，例如添加thread才能使用多线程库。

warn_on -告诉qmake要把编译器设置为输出警告信息的。

release -告诉qmake应用程序必须被连编为一个发布的应用程序。在开发过程中，程序员也可以使用debug来替换release。

c++11 -使用C++11的特性

6. 指定生成的应用程序放置的目录

DESTDIR += ../bin

7. 指定uic命令将.ui文件转化成ui_*.h文件的存放的目录

UI_DIR += forms

8. 指定rcc命令将.qrc文件转换成qrc_*.h文件的存放目录

RCC_DIR += ../tmp

9. 指定moc命令将含Q_OBJECT的头文件转换成标准.h文件的存放目录

MOC_DIR += ../tmp

10. 指定目标文件(obj)的存放目录

OBJECTS_DIR += ../tmp

11. 程序编译时依赖的相关路径

DEPENDPATH += . forms include qrc sources

12. 头文件包含路径

INCLUDEPATH += 

13. 执行qmake时输出消息

message(XXX) 会在执行qmake时输出括号中的内容

14. 获取系统参数

如 $$(PATH) 可以读取环境变量中的PATH

15. 平台相关性处理

我们在这里需要做的是根据qmake所运行的平台来使用相应的作用域来进行处理。为Windows平台添加的依赖平台的文件的简单的作用域看起来就像这样：

win32 {
SOURCES += hello_win.cpp
}

unix {
LIBS += -L$$PWD/linuxlib/ -lavfilter 
}

Linux或Unix使用作用域unix。

16. 使用系统命令

主要是使用system关键字

例如拷贝文件到指定目录

win32 {
    src_dir = $$PWD\Resources\*.*
    CONFIG(debug, debug|release) {
        dst_dir = $$OUT_PWD\\debug\\Resources\\
    } else {
        dst_dir = $$OUT_PWD\\release\\Resources\\
    }

    # dst_dir 最后的 \\ 是必须的，用来标示 xcopy 到一个文件夹，若不存在，创建之

    # Replace slashes in paths with backslashes for Windows
    src_dir ~= s,/,\\,g
    dst_dir ~= s,/,\\,g

    !exists($$dst_dir):system(xcopy $$src_dir $$dst_dir /y /e)
}